ONLY DO WHAT ONLY YOU CAN DO

こけたら立ちなはれ 立ったら歩きなはれ

VBScript で iTunes にインポートする

Option Explicit

Dim excelApp
Set excelApp = CreateObject("Excel.Application")
excelApp.Visible       = True
excelApp.DisplayAlerts = False '警告メッセージをOFF

Dim iTunesApp
Set iTunesApp = WScript.CreateObject("iTunes.Application")

'ブックを読み取り専用で開く
Dim book
Set book = excelApp.Workbooks.Open(WScript.Arguments(0), False, True)

Dim sheet
Set sheet = book.WorkSheets.Item(WScript.Arguments(1))

WScript.StdOut.WriteLine "登録開始..."

Dim artist: artist = ""
dim album : album  = ""

Dim iRow: iRow = 0
Dim row
For Each row In sheet.Cells.CurrentRegion.Rows
    iRow = iRow + 1
    If iRow > 1 Then
        If row.Columns(2) <> "" Then
            artist = row.Columns(2)
        End If

        If row.Columns(5) <> "" Then
            album = row.Columns(5)
        End If

        WScript.StdOut.WriteLine row.Columns(1)

        Dim sts
        Set sts = iTunesApp.ConvertFile(row.Columns(1))

        Do While (sts.InProgress)
            WScript.Sleep 1000
        Loop

        Dim track
        For Each track In sts.Tracks
            track.Artist       = artist
            track.Album        = album
            track.TrackNumber  = row.Columns(8)
            track.Name         = row.Columns(9)
            track.Composer     = row.Columns(11) & " & " & row.Columns(12)
        Next
        Set sts       = Nothing

    End If
Next

For Each track In iTunesApp.LibraryPlaylist.Tracks
    WScript.StdOut.Write      track.Artist       & ","
    WScript.StdOut.Write      track.Album        & ","
    WScript.StdOut.Write      track.TrackNumber  & ","
    WScript.StdOut.Write      track.Name         & ","
    WScript.StdOut.Write      track.Duration     & ","
    WScript.StdOut.Write      track.Composer     & ","
    WScript.StdOut.Write      track.Bitrate
    WScript.StdOut.WriteLine
Next

WScript.StdOut.WriteLine "登録終了"

iTunesApp.Quit
Set iTunesApp = Nothing

excelApp.Quit 
Set excelApp = Nothing